EXCEL - Funktion "WENN" - Seite 1 (von 6)

BedingungJA - "DANN"NEIN - "SONST"

WENN

Nein - Teil Ja - Teil

Die logische Funktion WENN

Zweck und Beispiele Eine Funktion "Wenn" kommt in praktisch allen Programmiersprachen vor. Meistens wird

dabei eine Art "Wenn ... dann ... sonst" (IF .. THEN .. ELSE) verwendet. Eine verkrzte Form

"Wenn ... dann" ist mglich. Verschachtelungen sind auch erlaubt.

Allgemein ist der Aufbau

WENN

DANN

SONST

In EXCEL ist diese allgemeine Konstruktion auch vorhanden - aber nur in der "im Hinter-

grund vorhandenen" Sprache VBA = Visual Basic for Applications.

In EXCEL - Tabellenblttern ist bei der Anwendung der WENN-Funktion im Unterschied

zur allgemeinen Definition festgelegt, was bei "dann" und "sonst" erfolgen kann:

Die Funktion ist in einer Zelle des Blatts geschrieben, bei "dann" muss ein Ausdruck

stehen, der hinterher den Inhalt der Zelle bildet; analog fr "sonst".

Syntax: = WENN(Wahrheitsbedingung; Dann-Wert; Sonst-Wert)

Auf die korrekte Schreibweise achten!

3 Teile mit Strichpunkt dazwischen! Die Anwendung des Funktionsassistenten ist auch mglich.

Die "Hilfe" enthlt weitere erklrende Informationen.

Aktion: Die Zelle, in der die Formel steht, enthlt - je nach dem Ausgang der Prfung der

Wahrheitsbedingung - den Inhalt von "Dann" oder "Sonst". Bei "Dann" bzw. "Sonst" steht ein

Wert oder ein Ausdruck, der 1 Ergebnis liefert. Verschachtelungen sind mglich.

Beispiel 1: In der Zelle A4 steht eine Zahl, in Zelle B6 soll stehen:

falls die Zahl in A4 positiv ist, das doppelte der Zahl in A4;

falls die Zahl in A4 negativ ist, der Text "negative Zahl". (0 wird als negativ angesehen.)

Zuerst die logische Bedingung, auf die man sprachlich mit "Ja" / "Nein" oder "Trifft zu" bzw. "Trifft nicht zu" antworten knnte. Dahinter jeweils 1 Ausdruck; dieser kann eine Zahl,

eine berechnete Zahl oder ein Text sein.

Eine mgliche "logische Bedingung" ist: Ist die Zahl in der Zelle A4 grer als Null? Der Inhalt der Zelle B6 soll dann sein:

falls JA: zweimal der Inhalt der Zelle A4 - also 1 Zahl.

falls NEIN: "negative Zahl" - also 1 Text.

Die Formel in der Zelle B6 lautet damit: =WENN(A4>0; 2*A4; "negative Zahl")

Texte mssen in EXCEL-Formeln durch Anfhrungszeichen gekennzeichnet sein.

Ausprobieren! Ob Sie die Formel direkt eintippen oder ber den Funktionsassistenten

erzeugen, ist Ihnen berlassen. Tipp: Anfnger probieren beides aus!

(1) In der Zelle B6 die obige Formel schreiben; dann in A4 verschiedene Zahlen einsetzen. (2) Was geschieht, wenn in A4 ein Text steht? (3) Geben Sie in A4 auch eine eingeklammerte Zahl (11) ein - was geschieht dann? (4) Was geschieht, wenn die Zelle A4 leer ist?

EXCEL - Funktion "WENN" - Seite 2 (von 6)

Lsungen zu den vorigen Aufgaben: (1) Sie haben hoffentlich die erwarteten Ergebnisse bekommen! Fr eine negative Zahl in A4

also in der Zelle B6 den Text "negative Zahl"; fr eine positive Zahl das doppelte dieser

Zahl. Fr die Zahl 0 in der Zelle A4 erhlt man den Text "negative Zahl" - wegen der Ab-

fragebedingung A4 grer als 0.

Falls die Formel nicht akzeptiert wird und EXCEL korrigieren will, haben Sie vielleicht

nicht beachtet: Die 1. Klammer muss ohne Leerzeichen direkt nach WENN stehen, hinter-

her sind Leerzeichen zur Erleichterung der Lesbarkeit erlaubt.

(2) EXCEL erwartet hier eine Zahl in der Zelle A4, damit der Vergleich >0 mglich ist. Deshalb erscheint die Fehlermeldung #WERT! als Kennzeichen eines falschen Datentyps.

(3) Eingeklammerte Zahlen werden in EXCEL als negative Zahlen interpretiert. (4) Eine leere Zelle enthlt nichts - und fr EXCEL ist das ein Zahlenwert 0; nach unserer ein-

fachen Konstruktion kommt dafr die Antwort "negative Zahl".

Beispiel 2: Ein zweites Beispiel zeigt eine Frage, fr die wieder je eine "Ja"- und eine "Nein"-

Antwort mglich ist. Die Syntax (Schreibweise der Formel) ist also gleich der von Beispiel 1.

Ein wenig nachdenken mssen Sie, wie der Aufgabentext in eine mathematische Formel

bersetzbar ist.

Aufgabe: In A1 und B1 stehen Zahlen. In C1 soll stehen:

wenn A1 grer als B1 ist : das Ergebnis "grere Zahl * 5 - kleinere Zahl * 2"

sonst: "grere Zahl +2 * kleinere Zahl" sonst.

A B C

1 12345 12345 ... WENN ...

Wir erwarten also als Beispiele:

= 4; = 5 13 (5 + 2 4)

= 7; = 5 25 (7 5 - 2 5)

berlegen Sie - nicht sofort die Lsung lesen!

Eine geeignete Frage, um die beiden Mglichkeiten zu unterscheiden Zwei Antworten dazu Beachten Sie die korrekte Schreibweise. In "Ja/Nein - Teil" werden nur die Ausdrcke und

nicht eine Zuweisung der Art "C1 = " geschrieben.

Lsung am Ende der Einfhrung!

Beispiel 3: Bei Verschachtelungen oder komplizierteren Abfragen ist die Verwendung eines Ablaufplans

("Flussdiagramm") oder einer tabellarischen Aufstellung der mglichen Flle sinnvoll und

erst dann die Umsetzung ("Codierung") in WENN-Anweisungen.

"=" kommt auch bei verschachtelten Ausdrcken nur einmal zu Beginn, als Kennzeichen fr

den Beginn einer Funktion, vor!

Aufgabe: Die Bedingungen des Beispiels 1 werden erweitert:

Inhalt der Zelle B6 ist

falls die Zahl in A4 positiv oder null ist, das doppelte der Zahl in A4;

falls die Zahl in A4 negativ und grer als -10 ist, der Text "negative Zahl".

falls die Zahl in A4 kleiner/gleich -10 ist (damit natrlich auch negativ), "zu klein!"

Offenkundig gengt nicht mehr 1 Bedingung! Die Verschachtelung erfordert zwei Fra-

gen:

1) Ist A4 positiv oder null? Wenn "nein", bleiben 2 Flle.

Also wird fr den "Nein-Zweig" wieder gefragt:

2) Ist A4 grer als -10? Wenn "ja", kommt der Text "negative Zahl".

Die dritte Mglichkeit - kleiner/gleich -10 - bleibt dann noch brig ("zu klein").

EXCEL - Funktion "WENN" - Seite 3 (von 6)

=

A4 >=0

A4 > -10 2 * A4

negativZu klein

J

J

N

N

Fr solche "komplizierteren Entscheidungen" ist ein Ablaufplan ("Flussdiagramm") ntzlich!

Der "Ja-Teil" der 1. Frage enthlt einen Ausdruck, der in der Zelle stehen soll. Der "Nein-

Teil" enthlt eine 2. Frage; an den Ausgngen dieser 2. Frage stehen zwei Texte, die in der

Zelle B6 erscheinen sollen.

Die EXCEL-Formel in der Zelle B6 ist

=WENN(A4>=0; 2*A4; WENN(A4>-10; "negative Zahl"; "zu klein!"))

Mit verschiedenen Zahlenwerten ausprobieren! (Es wird dabei auch deutlich, dass bei ver-

schachtelten WENN-Funktionen das direkte Eintippen der Formel einfacher ist, als die Ver-

wendung des Funktionsassistenten.)

Beispiel 4: Wie lautet die Formel, wenn die erste Abfrage "A4 < 0" anstelle von "A4 0" ist?

(Die Ergebnisse mssen natrlich identisch denen aus Beispiel 3 sein!)

Lsung am Ende der Einfhrung!

Beispiel 5: In den bisherigen Beispielen strt die Fehlermeldung, falls Text anstelle der er-

warteten Zahlen vorliegt. Hier ist die Erweiterung der Formel aus Beispiel 4 gezeigt.

Die Formel wird erweitert: Eine Abfrage wird davorgesetzt, die berprft, ob Text vor-

liegt.

In der Funktionskategorie "Information" gibt es eine geeignete Funktion: "IstText".

Ausprobieren!

=WENN(ISTTEXT(A4); "---"; WENN(A4>=0; 2*A4; WENN(A4>-10; "negative Zahl"; "zu klein!")))

Wenn ISTTEXT zutrifft, wird im "Ja-Teil" "---" in der Zelle angezeigt, im "Nein-Teil" folgen

die bisherigen Abfragen und Ergebnisse.

Lsung zum Beispiel 2

Weil in C1 ein Ergebnis stehen soll, steht die Formel auch in der Zelle C1

Eine Entscheidung ist durch den Ausdruck "A1 > B1" mglich.

DANN: Falls "ja" gilt, ist das Ergebnis "5 * A1 - 2 * B1"

SONST: Falls "nein" gilt, ist das Ergebnis "B1 + 2 * A1"

Der Fall A1 = B1 ist im SONST-Teil enthalten.

"Grere/kleinere Zahl" ist also durch die Schreibweise der Formeln im "Ja/Nein - Teil" be-

rcksichtigt.

Die drei gefundenen Ausdrcke werden nun direkt in der Formel in der Zelle C1 hingeschrie-

ben. (EXCEL hilft dabei - vor allem Anfngern - mit einem Funktionsassistenten zur Erleichte-

rung der Eingabe.) In der Zelle C1 steht:

= WENN ( A1 > B1 ; 5 * A1 - 2 * B1 ; B1 + 2 * A1 )

EXCEL - Funktion "WENN" - Seite 4 (von 6)

Im JA- und NEIN-Teil werden also nur die Ausdrcke und nicht eine komplette Zuweisungs-

gleichung, z.B. C1 = 5 * A1 - 2 * B1 geschrieben!

Lsung zum Beispiel 4

Ansehen des Flussdiagramms zeigt, dass nur der JA- und NEIN-Teil der 1. Frage vertauscht

werden mssen! "Ja" gilt fr alle Zahlen -10 erfllt ist. "Nein" trifft fr alle Zahlen 0 zu; dafr kommt das Ergebnis

2*A4.

=WENN(A4-10; "negative Zahl"; "zu klein!" ) ; 2*A4 )

===============================================================

In allen AUFGABEN werden die Formeln jeweils in der zweiten Zeile erzeugt und dann durch Ziehen nach unten erweitert (Autoausfllen).

LSUNGEN am Ende - aber bitte zuerst selbst eine Lsung suchen!

Aufgabe 1

Fr die Zahlenreihe in B2, B3 ... soll in C2, C3, ... eine "Bewertung" ausgegeben werden.

Damit liee sich beispielsweise sofort ein "Ausreier" in einer Messreihe markieren; dies ist

bei Begutachtung von Datenmaterial in der Praxis sicher eine groe Hilfe!

Bedingung: Falls der Wert der Nachbarzelle (fr C2 also B2, usw.) grer als 20 ist, wird

ein Sternchen geschrieben, sonst bleibt die Zelle leer ("Nichts" - 2 Anfhrungszeichen "" -

oder Leerzeichen " " als Antwort in einem Zweig). Die Formel wird in C2 einmal geschrie-

ben und dann durch "Ziehen am Anfasserquadrat" nach unten erweitert. Die entwickelte For-

mel mit verschiedenen Zahlenwerten testen!

Wie lautet die Formel in der Zelle C9?

Aufgabe 2

Bei der Speicherung von Personeninformationen ist sinnvoll, anstelle der Anrede Herr oder

Frau einen Codebuchstaben m oder f zu verwenden. (Zustzlich liee sich noch festlegen, ob

ein "Dr." mnnlich oder weiblich ist; wir wollen hier nur die Anrede Herr/Frau verwenden.)

Variante 1: Es wird nur m oder f und sicher nichts Anderes geschrieben.

Variante 2: Es wird m oder f geschrieben, aber Fehleingaben sollen auch erkannt werden.

Als "falschen Code" schreiben wir in diesem Beispiel "unklar".

Wie lautet die Formel in der Zelle D4 bzw. E4?

1

2

3

4

5

A B C

Nr. der Messung Ergebnis Bewertung

1 17,0

2 23,4 *

3 15,9

usw.

1

2

3

4

5

6

A B C D E

NN VN Code Variante 1 Variante 2

Maier Klaus m Herr Herr

Mller Irene f Frau Frau

Schulze Detlev unklar Falscher Code!

usw.

Der Inhalt dieser Zelle hngt von der Art des "WENN" ab!

EXCEL - Funktion "WENN" - Seite 5 (von 6)

Aufgabe 3 (Erweiterung von Aufgabe 2)

Aus Nachname, Vorname und Codebuchstabe soll eine komplette Anrede erzeugt werden.

Als Codebuchstabe gilt "m" fr Herr, "f" fr Frau, andere Codes - ich habe "unklar" einge-

setzt - sollen ein der Adressenzeile den Text "... Falscher Code" liefern. Textteile knnen mit

"&" (nicht mit "+") verknpft werden.

Welche Formel steht in Zelle D3?

Aufgabe 4

Zu einer Zahl x soll je nach einem Codebuchstaben die Flche der entsprechenden geometri-

schen Figur berechnet werden.

Code = q: Flche des Quadrats mit der Seitenlnge x

Code = k: Flche des Kreises mit dem Durchmesser(!) x

Anderer Codebuchstabe: Text "Falscher Code"

Die Ergebnisse fr Quadrat und Kreis sind mit Textinformationen verknpft. Fr die berech-

nete Flche soll auf 2 Nachkommastellen gerundet werden. (Eine Ganzzahl wird dann aber

trotzdem als Ganzzahl angezeigt! Belassen Sie das so!)

Wie lautet die Formel in der Zelle C3?

Hilfen

Fr das Quadrat steht in x die Seitenlnge, die Flche des Quadrats ist damit x2.

Die Flche eines Kreises mit dem Radius r ist r2 . In x steht aber der Durchmesser, der

Radius ist die Hlfte davon! Damit ist die Flche des Kreises x2 / 4. ist in EXCEL

durch den Funktionsausdruck PI() zu erhalten.

Zum Runden gibt es die EXCEL-Funktion " RUNDEN ( Zahl ; Nachkommastellen ) ". diese Funktion fhrt die Rundung nach der blichen "4/5-Regel" durch. "Fehlende" Stellenzah-

len werden aber nicht erzeugt. RUNDEN (4,567 ; 2) 4,57; RUNDEN (4,564 ; 2) 4,56;

RUNDEN (4,5 ; 2) 4,5; RUNDEN (4 ; 2) 4

Aufgabe 5 ( Die richtigen Funktionen sind zu suchen!)

In einer Tabelle mit Umstzen soll in einer benachbarten Spalte angezeigt werden, welche

Person den grten bzw. kleinsten Umsatz hat; dies wird mit "xxx" markiert. Hinweis: Die

EXCEL-Funktionen heien nicht "Grte" oder "Kleinste", sondern ? Schwierigkeiten kann

auch noch bereiten, dass die Formeln richtig so aufgebaut werden, dass sie durch Ziehen nach

unten ("Autoausfllen") erweiterbar sind.

1

2

3

4

5

A B C

x

Code

[q/k] Ergebnis

2,2 q Die Flche des Quadrats mit der Seitenlnge 2,2 ist 4,84

4,4 k Die Flche eines Kreises mit dem Durchmesser 4,4 ist 15,21

6,6 u Falscher Code

usw.

1

2

3

4

5

A B C D

NN VN Code Adresse

Maier Klaus m Herr Klaus Maier

Mller Irene f Frau Irene Mller

Schulze Detlev unklar ... Falscher Code

usw.

EXCEL - Funktion "WENN" - Seite 6 (von 6)

Um nach dem grten bzw. kleinsten Umsatz zu suchen, ist in dieser Aufgabe der Bereich

bekannt: Die Daten gehen nur bis zum Eintrag "Amsel"! (Bereich B2 bis B8)

Wie lauten die Formeln in den Zellen C4 und D4?

===============================================================

Lsungen

1) 1 Bedingung verknpft die Zelle mit der linken Nachbarzelle =WENN (B9 > 20; "*" ; " ")

2) Bei Variante 1 schliet ein Fall den anderen aus. Entweder ist "m" ein Herr und alles An-

dere - es kann nur "f" vorkommen - eine Frau. Damit hngt der Inhalt eines Felds mit fal-

schem Code davon ab, ob nach "m" oder "f" gefragt wurde.

D4: = WENN(C4="m"; "Herr"; "Frau") oder =WENN(C4="f"; "Frau"; "Herr")

Bei Variante 2 ist ein verschachteltes WENN ntig:

E4: = WENN(C4="m"; "Herr"; WENN(C4="f"; "Frau"; "Falscher Code!") )

Der dritte Fall (Falscher Code) entsteht durch Ausschlieung ber "m" oder "f".

Beachten: Textteile, also auch Buchstaben, mssen in Anfhrungszeichen stehen! Es

muss also C4 = "m" heien! Bei C4 = m wird m von EXCEL als "Name einer

Zelle" interpretiert und man erhlt die Fehlermeldung " #NAME? "! Nicht verwechseln: In

der Zelle selbst kann ein Text ohne Anfhrungszeichen geschrieben werden, in Formeln

sind die Anfhrungszeichen notwendig.

3) Je nach Codebuchstabe Herr/Frau auswhlen; Leerzeichen bei der Verknpfung beachten!

Abfrage nach Code "m", dann "f", als Rest bleibt ein ungltiger Code. =WENN(C3="m"; "Herr " & B3 & " " & A3; WENN(C3="f";"Frau " & B3 & " " & A3; "... Falscher Code"))

4) hnliche Logik wie schon erarbeitet: zuerst Code = q?, dann Code = k?, bleibt ungltiger

Code brig! Runden auf 2 Nachkommstellen mit "Runden"; die Anzeige auch ganzer Zah-

len ohne 2 Nachkommastellen ist damit nicht zu verhindern (wird aber bei dieser Aufgabe

belassen). Text und Zahlen werden mit "&" verknpft; die Formeln zur Flchenberechnung

werden direkt in die WENN-Bedingung geschrieben.

=WENN(B3="q";"Die Flche des Quadrats mit der Seitenlnge " & A3 & " ist " & RUNDEN(A3*A3;2); WENN(B3="k";"Die Flche eines Kreises mit dem Durchmesser " & A3 & " ist " & RUNDEN(A3*A3*PI()/4;2); "Falscher Code"))

5) Minimum (EXCEL: MIN) und Maximum (EXCEL: MAX) als bentigte Funktionen. Ein Wert

ist dann der grte, wenn er gleich dem grten Wert aus einer Liste ist! Bei der Erstellung

der Formel ist wichtig, dass der Bereich der ganzen Liste absolut adressiert ist! Nur so

bleibt beim "Ziehen" der Formel dieser Bereich erhalten.

C4: =WENN(B4=MAX($B$2:$B$8);"xxx";" ") D4: =WENN(B4=MIN($B$2:$B$8);"xxx";" ")